MicroPi > Мини ПК > Arduino > Arduino проекты

Подключение цифрового люксметра (датчика освещенности) BH1750 к Arduino

Для измерения освещенности отлично подходят модули Gy-30 и Gy-302 на базе сенсора BH1750. Сенсор предназначен для измерения фонового освещения, имеет высокую чувствительность, а спектр чувствительности совпадает с кривой чувствительности человеческого глаза. Подключается BH1750 к Arduino по распространенному I2C интерфейсу. Внутренняя логика BH1750 избавляет от необходимости каких-либо сложных вычислений, поскольку он напрямую выводит значимые цифровые данные в люксах (лк). С помощью BH1750 можно изготовить самодельный люксметр на Ардуино.

Установка библиотеки BH1750

Библиотеку можно установить из самой среды следующим образом:

  1. Скачиваем библиотеку BH1750 с github;
  2. В Arduino IDE открываем менеджер библиотек: Скетч->Подключить библиотеку->Добавить .ZIP библиотеку…Подключение дальномера HC-SR04 к Arduino - Добавить .ZIP библиотеку...
  3. Выбираем .ZIP архив и кликаем Open/Открыть.Подключение цифрового люксметра BH1750 к Arduino - Выбор архива .ZIP
  4. Библиотека установлена.Подключение цифрового люксметра BH1750 к Arduino - Библиотека BH1750 установлена

Подключение BH1750 к Arduino

Модуль модуль GY-302 оборудован пяти-пиновым разъемом стандарта 2.54мм:

  • VCC: Питание «+»
  • GND: Земля «-«
  • SCL: Линия тактирования (Serial CLock)
  • SDA: Линия данных (Serial Data)
  • ADDR: Выбор адреса

Выводы отвечающие за интерфейс I2C на платах Arduino на базе различных контроллеров разнятся:

Arduino Mega Arduino Uno/Nano/Pro Mini BH1750 модуль Цвет проводов на фото
GND GND GND Черный
5V 5V VCC Красный
20 (SDA) A4 SDA Синий
21 (SCL) A5 SCL Зелёный
3.3V 3.3V ADDR Жёлтый

Схема подключения BH1750 к Arduino по I2C

На следующем рисунке показана схема подключения датчика внешней освещенности BH1750 к Arduino UNO. Вывод ADD можно оставить «висящим»:

Схема подключения BH1750 к Arduino по I2C без ADDR

но вы можете подключить его к 3.3 В. Это переведет вывод ADD в высокий логический уровень, и адрес ведомого I2C датчика внешней освещенности BH1750 станет 0x5C. Это важно в программировании. Если вывод ADD переведен в низкое логическое состояние путем подключения к земле, адрес ведомого устройства I2C датчика внешней освещенности BH1750 будет 0x23. Таким образом, два датчика внешней освещенности BH1750 могут быть подключены к одной шине I2C, где один вывод ADD имеет низкое логическое состояние, а другой вывод ADD высокое.

Схема подключения BH1750 к Arduino по I2C с ADDR

Пример скетча

В скетче мы каждые 1000 мсек считываем с датчика BH1750 показания освещённости в люксах и выводим эти данные в последовательный порт.

/*
   Подключяем библиотеку Wire (для I2C)
*/
#include <Wire.h>
/*
   Подключяем библиотеку для bh1750
*/
#include <BH1750.h>
/*
   Объявляем объект lightMeter
*/
BH1750 lightMeter;

void setup() {
  /*
     Запускаем последовательный порт
  */
  Serial.begin(9600);
  /*
    Инициализируем шину I2C (библиотека BH1750 не делает это автоматически)
    На esp8266 вы можете выбрать выводы SCL и SDA, используя Wire.begin (D4, D3);
  */
  Wire.begin();
  /*
    Инициализируем и запускаем BH1750
  */
  lightMeter.begin();

  Serial.println(F("BH1750 тест"));
}

void loop() {
  /*
    Считываем показания с BH1750
  */
  float lux = lightMeter.readLightLevel();
  /*
    Отправляем значение освещенности в последовательный порт
  */
  Serial.print("Light: ");
  Serial.print(lux);
  Serial.println(" lx");
  /*
     раз в секунду
  */
  delay(1000);
}

Результат

Открыть монитор последовательного порта можно сочетанием клавиш Ctrl+Shift+M или через меню Инструменты. В мониторе последовательного порта побегут значения освещённости с нашего датчика BH1750.

Подключение цифрового люксметра (датчика освещенности) BH1750 к Arduino - Результат

Сравнение BH1750 и TSL2561

Спектр видимого света колеблется от 380 нм (фиолетовый) до 780 нм (красный) (в вакууме). Короче говоря, BH1750 просто измеряет это. TSL2561, помимо видимого спектра, также измеряет инфракрасное излучение. Он имеет два диода, один для видимого, а второй для инфракрасного. На мой взгляд, BH1750 соответствует большинству требований, тогда как TSL2561 предлагает более широкий спектр, большую чувствительность и большую точность.

Для сравнения, оба датчика были размещены параллельно в макете, один рядом с другим. Таким образом, можно получить практически одинаковое излучение на оба датчика.

Более подробно о том, как работать с TSL2561 в Ардуино, можете найти в отдельной статье Подключение цифрового датчика освещенности TSL2561 к Arduino.

Схема подключения TSL2561 и BH1750 к Arduino по I2C

На следующем рисунке показана схема подключения датчиков внешней освещенности TSL2561 и BH1750 к Arduino UNO.

Схема подключения TSL2561 и BH1750 к Arduino по I2C без ADDR

Пример скетча

#include <Wire.h>
#include <BH1750.h>
#include <Adafruit_TSL2561_U.h>

BH1750 bh1750;
Adafruit_TSL2561_Unified tsl2561 = Adafruit_TSL2561_Unified(TSL2561_ADDR_FLOAT, 12345);

void setup() {
  Serial.begin(9600);
  Wire.begin();

  /*
     TSL2561
  */
  if (!tsl2561.begin()) {
    Serial.print(F("При обнаружении TSL2561 возникла проблема ... проверьте подключение!"));
    while (1);
  }

  tsl2561.setGain(TSL2561_GAIN_1X);
  tsl2561.setIntegrationTime(TSL2561_INTEGRATIONTIME_402MS);

  /*
    BH1750
  */
  bh1750.begin(BH1750::ONE_TIME_HIGH_RES_MODE);

  Serial.println(F("BH1750 vs TSL2561"));
}

void loop() {
  /*
    Считываем показания с TSL2561
  */
  sensors_event_t event;
  tsl2561.getEvent(&event);
  /*
    Считываем показания с BH1750
  */
  float lux = bh1750.readLightLevel();
  /*
    Отправляем значение освещенности в последовательный порт
  */
  if (event.light) {
    Serial.print(F("TSL2561: "));
    Serial.print(event.light);
    Serial.println(F(" lx"));
  } else {
    /*
      Если event.light = 0 люкса датчик, вероятно, насыщенные
      и достоверные данные не может быть сгенерированы!
    */
    Serial.println(F("Насыщенные TSL2561"));
  }
  Serial.print(F("BH1750 : "));
  Serial.print(lux);
  Serial.println(F(" lx"));

  delay(1000);
}

Результат

По результатам TSL2561 и BH1750 дают практически идентичные показатели в одинаковых условиях. Это говорит о том, что сами датчики идут откалиброванными с завода.

Сравнение BH1750 и TSL2561 (BH1750 vs TSL2561)

Материалы

datasheet bh1721fvc-e.pdf
GitHub — claws/BH1750: An Arduino library for the digital light sensor breakout boards containing the BH1750FVI IC
BH1750 — Цифровой датчик освещенности/люксметр — MicroPi

Похожие записи

Комментарии 53

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *

➤